На главную... Продукты | Технологии | Классификаторы | Проекты | Скачать | Цены| Форум | Статьи | Обучение | Контакты

Невалидный файл проекта qmapcomponents.pro

Поиск  Пользователи  Правила  Войти
Форум » Linux » Средства разработки ГИС-приложений для Linux
Страницы: 1
RSS
Невалидный файл проекта qmapcomponents.pro
 
Невалидный файл проекта qmapcomponents.pro в исходниках для версии ГИС Конструктор для Qt Designer x64 (версия 12.6.1, Qt 4, Qt 5, платформа x64, ОС "Astra Linux Special Edition", релиз "Смоленск") выложенной на вашем ресурсе.

Как минимум отсутствуют закрывающие скобки:
Код
eval (GIS_DOUBLE_QT == true ) {
  greaterThan(QT_MAJOR_VERSION, 4) {

После того, как я закомментировал этот код, а также использование designer для Qt5, т.к. почему-то не находит он у меня в астре этот модуль и попытался собрать, выдало следующие ошибки:
Цитата
g++ -c -m64 -pipe -O2 -D_REENTRANT -Wall -W -fPIC -DHIDE_3DSUPPORT -DHIDE_GISSERVER_SUPPORT -DHIDEMAXMIN -DQT_NO_DEBUG -DQT_PLUGIN -DQT_PRINTSUPPORT_LIB -DQT_WIDGETS_LIB -DQT_GUI_LIB -DQT_CORE_LIB -I. -isystem /usr/include/gisdesigner -isystem /usr/include/x86_64-linux-gnu/qt5 -isystem /usr/include/x86_64-linux-gnu/qt5/QtPrintSupport -isystem /usr/include/x86_64-linux-gnu/qt5/QtWidgets -isystem /usr/include/x86_64-linux-gnu/qt5/QtGui -isystem /usr/include/x86_64-linux-gnu/qt5/QtCore -I. -I/usr/lib/x86_64-linux-gnu/qt5/mkspecs/linux-g++-64 -o qdmdlist.o qdmdlist.cpp
g++ -c -m64 -pipe -O2 -D_REENTRANT -Wall -W -fPIC -DHIDE_3DSUPPORT -DHIDE_GISSERVER_SUPPORT -DHIDEMAXMIN -DQT_NO_DEBUG -DQT_PLUGIN -DQT_PRINTSUPPORT_LIB -DQT_WIDGETS_LIB -DQT_GUI_LIB -DQT_CORE_LIB -I. -isystem /usr/include/gisdesigner -isystem /usr/include/x86_64-linux-gnu/qt5 -isystem /usr/include/x86_64-linux-gnu/qt5/QtPrintSupport -isystem /usr/include/x86_64-linux-gnu/qt5/QtWidgets -isystem /usr/include/x86_64-linux-gnu/qt5/QtGui -isystem /usr/include/x86_64-linux-gnu/qt5/QtCore -I. -I/usr/lib/x86_64-linux-gnu/qt5/mkspecs/linux-g++-64 -o qdmdcmtw.o qdmdcmtw.cpp
qdmdcmtw.cpp:6:3: error: ‘PRIORMTRPARM’ does not name a type
make: *** [qdmdcmtw.o] Ошибка 1
Изменено: Сергей - 23.10.2019 14:51:14 (Более детальное описание)
 
Здравствуйте!
Для сборки библиотеки компонентов необходимо внести следующие изменения:
  • в файл qdmdcmtw.cpp добавить подключение заголовочного файла mtrexapi.h;
  • установить пакет qttools5-dev для сборки библиотеки компонентов с qt5;
  • обновить содержимое файла qmapcomponents.prо, текст которого привожу ниже.
Код
_BUILD_QT_DESIGNER_COMPONENTS = yes
TARGET = mapcomponents
TEMPLATE = lib

CONFIG += qt warn_on qt_no_compat_warning release plugin thread

SOURCES += \
  qdmcmp.cpp qdmcompa.cpp qdmdsel.cpp qdmfind.cpp qdmlayr.cpp qdmmet.cpp qdmmtr.cpp qdmobja.cpp \
  qdmobj.cpp qdmpoina.cpp qdmpoint.cpp qdmrst.cpp qdmselob.cpp qdmselt.cpp qdmsem.cpp \
  qdmsite.cpp qdmviewa.cpp qdmwina.cpp qdmwinw.cpp qdmact.cpp qdmrect.cpp \
  qdmconv.cpp qdmactpt.cpp qdmdlist.cpp \
  qdmdcmtw.cpp qdmdprn.cpp qdmdgtob.cpp qdmvport.cpp qdmgsrv.cpp qdmd3d.cpp qdmnet.cpp qdmdwmspopup.cpp \
  qdmactline.cpp qdmanimator.cpp

HEADERS += \
  qdmcmp.h qdmcompa.h qdmdsel.h qdmfind.h qdmlayr.h qdmmet.h qdmmtr.h qdmobja.h \
  qdmobj.h qdmpoina.h qdmpoint.h qdmrst.h qdmselob.h qdmselt.h qdmsem.h \
  qdmsite.h qdmviewa.h qdmwina.h qdmwinw.h \
  qdmact.h qdmrect.h qdmconv.h qdmactpt.h \
  qdmdlist.h qdmdcmtw.h qdmdprn.h \
  qdmdgtob.h qdmvport.h qdmgsrv.h qdmd3d.h qdmnet.h qdmdwmspopup.h \
  qdmactline.h qdmanimator.h

!isEmpty( _HIDE_3DSUPPORT ) {
  SOURCES -= qdmd3d.cpp
  HEADERS -= qdmd3d.h
  DEFINES += HIDE_3DSUPPORT
}
!isEmpty( _HIDE_PRINTSUPPORT ) {
  SOURCES -= qdmdprn.cpp
  HEADERS -= qdmdprn.h
  DEFINES += HIDE_PRINTSUPPORT
}
!isEmpty( _HIDE_GISSERVER_SUPPORT ) {
  SOURCES -= qdmgsrv.cpp
  HEADERS -= qdmgsrv.h
  DEFINES += HIDE_GISSERVER_SUPPORT
}

!isEmpty( _BUILD_QT_DESIGNER_COMPONENTS ) {
  greaterThan(QT_MAJOR_VERSION, 4) {
    QT += designer
  } else {
    CONFIG += designer
  }
  SOURCES += qdmapcomp.cpp qdmapcomp_plugin.cpp
  HEADERS += qdmapcomp_plugin.h qdmapcomp.h
}

greaterThan(QT_MAJOR_VERSION, 4) {
  QT += widgets printsupport
}

DEFINES += HIDEMAXMIN GIS_DESIGNER

target.path  = $$[QT_INSTALL_PLUGINS]/designer
INSTALLS    += target
INCLUDEPATH += /usr/include/gisdesigner/
LIBS += -lqdmapacces -lqdobjnet

После данных изменений сборка должна происходить корректно. Исправление войдет в следующую версию ГИС Конструктор.

Спасибо!

 
Цитата
Константин Ганюшин написал:
После данных изменений сборка должна происходить корректно. Исправление войдет в следующую версию ГИС Конструктор.
Да, спасибо. Все собралось из консоли.

Но при открытии файла проекта в QtCreator все зависает и через некоторое время QtCreator "падает".
Изменено: Сергей - 28.10.2019 15:37:19 (Добавлено описание падения QtCreator)
 
Здравствуйте!

Прошу прощения за задержку с ответом.

С подобным поведением мы сталкивались при работе с Qt Creator из состава Astra Linux 1.5. Данное поведение обсуждалось в этой ветке форума:
http://www.gisweb.ru/forum/forum2/10254-primery-gis-designer
 
Цитата
Александр Савелов написал:
С подобным поведением мы сталкивались при работе с Qt Creator из состава Astra Linux 1.5. Данное поведение обсуждалось в этой ветке форума:
Спасибо, Александр.
Страницы: 1
Читают тему (гостей: 1)



© КБ Панорама, 1991-2024

Регистрируясь или авторизуясь на форуме, Вы соглашаетесь с Политикой конфиденциальности